ANSYS時(shí)程分析重啟動(dòng)例子 【轉(zhuǎn)】

這是自己最近做的一個(gè)例子,一是為了感謝okok論壇給與我的很大的幫助,二是起到拋磚引玉的作用.因?yàn)槲矣X得這個(gè)技術(shù)是很有用的,特別是對于計(jì)算時(shí)間特別長的模型,可以分成幾段計(jì)算,這可以避免由于意外中斷等原因重復(fù)以前的計(jì)算工作.下面時(shí)我的命令流(經(jīng)過驗(yàn)證與沒有使用重啟動(dòng)分析結(jié)果完全一致):
finish
/clear,nostart !
/config,nres,2000
/CWD,'E:\graduate design\FEM\beam\transient\seismic\restart'
/filnam,restart,1
/title,restart
/PREP7
ET,1,BEAM3
R,1,1,0.83333e-1,1, , , ,
MP,EX,1,200e9
MP,DENS,1,7.8e3
N,1
N,201,200
FILL
E,1,2
EGEN,200,1,1
D,1,UX,,,,,Uy
D,201,Uy
finish

/SOLU! Enter SOLUTION
ANTYPE,TRANS! Transient analysis
TRNOPT,FULL! Full method
rescontrol,define,50,last!將第50載荷步的最后一個(gè)子載荷步寫入.Rnnn文件
rescontrol,define,100,last!將第100載荷步的最后一個(gè)子載荷步寫入.Rnnn文件
!另外默認(rèn)的還會(huì)將最后一個(gè)載荷步的最后一個(gè)子載荷步寫入.Rnnn文件
!
!從文件中讀取地震波付給數(shù)組
*dim,tjwe,,1000,1
*dim,tjns,,1000,1
*dim,tjud,,1000,1

*CREATE,ansuitmp
*VREAD,tjwe,'tjwe1D','txt',' ',1, , , , , ,
(F7.4)
*END
/INPUT,ansuitmp
!*
*CREATE,ansuitmp
*VREAD,tjns,'tjns1D','txt',' ',1, , , , , ,
(F7.4)
*END
/INPUT,ansuitmp
!*
*CREATE,ansuitmp
*VREAD,tjud,'tjud1D','txt',' ',1, , , , , ,
(F7.4)
*END
/INPUT,ansuitmp
deltt=0.01!測量時(shí)間間隔.01s
betad,0.1462
KBC,0
outres,basic,all
parsave,all,parameter!保存參數(shù),這對下面的重分析是必須的,因?yàn)檫@些參數(shù)是沒有存入.RDB文件的
*status!列出APDL信息
*do,i,1,500,1
acel,tjwe(i),tjns(i),tjud(i)
time,i*deltt
nsubst,1
solve
*enddo
rescontrol,file_summary
finish
!重啟動(dòng)分析
/solu
antype,,restart,500,1
parres,,parameter!重新載入?yún)?shù)
*status
rescontrol,define,700,last!將第700載荷步的最后一個(gè)子載荷步寫入.Rnnn文件
rescontrol,define,800,last!將第800載荷步的最后一個(gè)子載荷步寫入.Rnnn文件

*do,i,501,1000,1
acel,tjwe(i),tjns(i),tjud(i)
time,i*deltt
nsubst,1
solve
*enddo
rescontrol,file_summary
finish

/post26
NSOL,2,101,U,Y,UY_2
XVAR,1
PLVAR,2
/gropts,view,1!可以使圖形能夠用鼠標(biāo)進(jìn)行縮放