搜索哪種桁架更安全合理？清晰合理的受力形式，實現(xiàn)材料充分利用
2017-02-20 by:CAE仿真在線 來源:互聯(lián)網(wǎng)
導讀:根據(jù)生活常識和所學知識,首先定性分析,然后定量計算分析。
一、問題描述
這兩種桁架,哪一個更安全合理一些?
二、問題分析
初看之下,只有腹桿的方向相反。但是細細想一下,發(fā)現(xiàn)腹桿反向差別很大,甚至兩種桁架的受力狀態(tài)完全不同:
桁架1:直接判斷6,9,12全是零桿。再者,根據(jù)節(jié)點靜力平衡,1,8,14,15均為壓桿,沿2,8,15桿“切一刀”,根據(jù)截面平衡法,2是拉桿(支座處沒有水平力)。這樣,整個桁架相當于兩個平行四邊形組成的“半圓拱”,下部用兩根拉桿相連。外側(cè)的兩個集中荷載由單柱承受。這樣的結(jié)構(gòu)是很不合理的,不但浪費材料,而且壓桿穩(wěn)定性也很難保證。顯然這樣不合理的結(jié)構(gòu)是不能采取的。
桁架2:底部弦桿1和4是零桿。傾斜的腹桿均受拉(腹桿較長,受壓比較危險!),形成一個倒梯形的有效受力桁架體系,各桿能發(fā)揮作用,材料利用率較高。所以說,桁架2是比桁架1更安全合理的結(jié)構(gòu)。
三、結(jié)果分析與討論
建模計算需要的參數(shù)有:橫桿和豎桿的長度為0.2m,橫截面面積為100 mm2,彈性模量E= 200 GPa,泊松比u = 0.3,載荷F = 1 kN。
經(jīng)過ANSYS建模計算,以下是兩桁架的軸力圖和軸力列表,可見上述定性分析是正確的。
(1)桁架1的軸力圖
(2)桁架2的軸力圖
(3)桁架1和桁架2的軸力計算結(jié)果對比
這只是個小例子,但由此可以體會到,結(jié)構(gòu)中材料的充分利用是要依靠清晰合理的受力形式。當能做到用最省的材料承受最大的荷載時,才是最經(jīng)濟合理的結(jié)構(gòu)。結(jié)構(gòu)的美在于簡單精巧,沒有冗余!
四、GUI求解步驟
1.進入ANSYS
程序→ ANSYS → ANSYS Product Launcher → 改變working directory到指定文件夾→ 在job name輸入:Link → Run。job name可默認為file。
2.定義工作文件名及工作標題
(1)定義工作文件名:UtilityMenu > File > Change Jobname → Change Jobname → 輸入文件名Link→ OK?？刹挥幂斎?默認為file。
(2)定義工作標題:UtilityMenu > File > Change Title → Change Title → 輸入Link→ OK。可不用輸入。
3.定義單元屬性
(1)定義單元類型:MainMenu > Preprocessor > Element Type > Add/Edit/Delete → Add → 在左列表框中選擇Link,在右列表框中選擇3D finit stn 180 → OK → Close。
(2)定義實常數(shù):MainMenu > Preprocessor > Real Constants > Add → Type 1 → OK → RealConstant Set No.:1,AREA:100→ OK → Close。
(3)設置材料屬性:MainMenu > Preprocessor > Material Props > Material Models → Structural→ Linear → Elastic → Isotropic → EX:2.0E5,PRXY:0.3→ OK。
4.建立模型
(1)定義節(jié)點:MainMenu > Preprocessor > Create > Nodes > In Active CS → 依次輸入10個節(jié)點的節(jié)點編號和坐標→OK。
(2)定義單元:
①定義單元:MainMenu > Preprocessor > Create > Elements > Auto Numbered > Thru Nodes → 按照桿的編號,依次拾取節(jié)點,生成單元→ OK。
②打開節(jié)點和單元編號:Utility Menu > PlotCtrls > Numbering→ NODE numbers:ON,Elem/Attribnumbering: Element numbers。→ OK。
③顯示單元:Utility Menu > Plot > Element,查看節(jié)點和單元編號。
④打開桿單元的單元形狀:Utility Menu > PlotCtrls> Style > Size and Shape → [/ESHAPE]: On。
5.施加邊界條件并求解
(1)施加約束:MainMenu > Solution > Define loads > Apply > Structural > Displacement> On Nodes → 拾取節(jié)點1→ OK → Lab2:AllDOF → Apply → 拾取節(jié)點9→Lab2:UY→ OK。
(2)在上排節(jié)點施加載荷:
①選擇上排節(jié)點:UtilityMenu >Select >Entities → 見下圖→OK。
②施加載荷:MainMenu > Solution > Define loads > Apply > Structural > Force/Moment> On Nodes → Pick All → Lab:FY,VALUE:-1e3→ OK。
③選擇所有:UtilityMenu >Select >Everything。求解器前務必選擇所有,否則計算失敗。
(3)求解前保存模型:UtilityMenu > Files > Save as → 輸入Link_Load.db→ OK。
6.求解
(1)求解:MainMenu > Solution > Solve > Current LS → File > Close → Solve CurrentLoad Step → OK → Solution is done → Close。
(2)保存結(jié)果文件:UtilityMenu > Files > Save as → 輸入Link_Solve.db→ OK。
7.軸力后處理
(1)查定義LINK180軸力單元表的方法:打開ANSYSHelp,搜索LINK180。
找到LINK180的單元介紹頁面后,找Table180.1: LINK180 Element OutputDefinitions,在Name欄中FORCE便是軸力。
找Table 180.2:LINK180 Item and Sequence Numbers,表中OutputQuantity Name列找到FORCE,Item為SMISC,編號為1。
(2)定義軸力單元表:MainMenu > General Postproc > Element Table > Define Table,→ Lab:輸入FN→ Item:選擇Bysequence num → Comb:選擇SMISC,在SMISC后面輸入“1” → OK → Close。
(3)軸力列表顯示:Main Menu > General Postproc > Element Table> List Element Table → 選擇FN → OK → 記錄各個單元的軸力 → File → Close。
(4)畫軸力圖:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI選擇FN,LabJ選擇FN→ OK。
8.退出ANSYS軟件
Utility Menu> File > Exit → Quit-No Save → OK。
五、APDL求解步驟
!--------------------------------------------第1種桁架
/PREP7 !進入前處理
ET,1,LINK180 !單元類型1
R,1,100 !實常數(shù)1
MP,EX,1,2.0e5 !材料1
MP,PRXY,1,0.3
N,1,0,0,0 !定義節(jié)點
N,2,0,0.2e3,0
NGEN,5,2,ALL, , ,0.2e3, , ,1,
E,1,3 !定義單元
E,3,5
E,5,7
E,7,9
E,9,10
E,10,8
E,8,6
E,6,4
E,4,2
E,1,2
E,3,4
E,5,6
E,7,8
E,1,4 !斜桿
E,3,6
E,6,7
E,8,9
FINISH
/SOLU !進入求解器
D,1,ALL !施加約束
D,9,UY
NSEL,S,LOC,Y,0.2e3 !由y坐標選擇節(jié)點
F,ALL,FY,-1e3 !施加載荷
ALLSEL,ALL !選擇所有
SOLVE !求解
FINISH
/POST1 !后處理
ETABLE,FN,SMISC, 1 !定義軸力單元表
PRETAB,FN !列表顯示軸力單元表
PLLS,FN,FN,1,0 !云圖顯示軸力圖
!--------------------------------------------第2種桁架
/PREP7 !進入前處理
ET,1,LINK180 !單元類型
R,1,100 !實常數(shù)
MP,EX,1,2.0e5 !材料
MP,PRXY,1,0.3
N,1,0,0,0 !定義節(jié)點
N,2,0,0.2e3,0
NGEN,5,2,ALL, , ,0.2e3, , ,1,
E,1,3 !定義單元
E,3,5
E,5,7
E,7,9
E,9,10
E,10,8
E,8,6
E,6,4
E,4,2
E,1,2
E,3,4
E,5,6
E,7,8
E,2,3 !斜桿
E,4,5
E,5,8
E,7,10
FINISH
/SOLU !進入求解器
D,1,ALL !施加約束
D,9,UY
NSEL,S,LOC,Y,0.2e3 !由y坐標選擇節(jié)點
F,ALL,FY,-1e3 !施加載荷
ALLSEL,ALL !選擇所有
SOLVE !求解
FINISH
/POST1 !后處理
ETABLE,FN,SMISC, 1 !定義軸力單元表
PRETAB,FN !軸力列表
PLLS,FN,FN,1,0 !軸力云圖
來源:程曉波的博客,結(jié)構(gòu)定性分析例四。好學ANSYS整理,并用ANSYS進行了計算。
相關(guān)標簽搜索：哪種桁架更安全合理？清晰合理的受力形式，實現(xiàn)材料充分利用 Ansys有限元培訓 Ansys workbench培訓 ansys視頻教程 ansys workbench教程 ansys APDL經(jīng)典教程 ansys資料下載 ansys技術(shù)咨詢 ansys基礎(chǔ)知識 ansys代做 Fluent、CFX流體分析 HFSS電磁分析 Abaqus培訓
